Du bist nicht angemeldet.

#1 21.02.2016 19:28:53

Dedik
Mitglied

line6usb- driver PKGBUILD

Hallo,

ich habe auf meinem Audio-Workstation-Rechner 32bit archlinux installiert. Ich bin begeistert!
Mit meiner M-Audio Delta 44 nehme ich mit 0 XRuns auf.
Also alles bestens.

Jetzt hat mir ein Freund ein line6 Audiointerface gegeben : line6 UX2.
Nach einiger Recherche war klar, das das linux support hat eine Softwaresammlung zu line6 Produkten gibt es hier :  https://sourceforge.net/projects/line6linux/

Also Grund genug meine erste PKGBUILD -Datei anzulegen.
Nach einiger Einarbeitungszeit im arch-Wiki dachte ich eigentlich das System erfasst zu haben.
Leider bekomme ich aber beim makepkg Befehl eine Fehlermeldung wegen Syntaxfehlern.

Meine 'PKGBUILD siht bisher so aus:

# Maintainer: DirkKitsch <dikkitsch@unitybox.de>
pkgname=line6usb
pkgver=0.9.1beta
pkgrel=1
pkgdesc="usb driver for line6 ux2"
arch=(any)
url="https://sourceforge.net/projects/line6linux/"
license=('GPLv2')
groups=(line6linux)
depends=()
makedepends=('subversion')
source=("http://svn.code.sf.net/p/line6linux/code/driver/branches/ux2")

md5sums=('d899e5ac3ec66c8a9b7926445ec6ea1e') #generate with 'makepkg -g'

_svntrunk=SVNURL
_svnmod=MODNAME

build() {
  cd "$srcdir"
  msg "Connecting to SVN server...."

  if [[ -d "$_svnmod/.svn" ]]; then
    (cd "$_svnmod" && svn up -r "$pkgver")
  else
    svn co "$_svntrunk" --config-dir ./ -r "$pkgver" "$_svnmod"
  fi

  msg "SVN checkout done or server timeout"
  msg "Starting build..."

  rm -rf "$srcdir/$_svnmod-build"
  svn export "$srcdir/$_svnmod" "$srcdir/$_svnmod-build"
  cd "$srcdir/$_svnmod-build"

  #
  # BUILD HERE
  #
  ./autogen.sh
  ./configure --prefix=/usr
  make
}

package() {
  cd "$srcdir/$_svnmod-build"
  make DESTDIR="$pkgdir/" install
}

Irgendwo liegt mein Denkfehler, ich weiß nur nicht wo?

Anregungen erwünscht!  smile

dedik

Offline

#2 21.02.2016 20:00:14

skull-y
Mitglied

Re: line6usb- driver PKGBUILD

Und wie lautet die Fehlermeldung bei makepkg?

Offline

#3 21.02.2016 23:20:22

michi
Mitglied

Re: line6usb- driver PKGBUILD

Funktioniert das Teil nicht mit dem snd-usb-line6 Modul aus dem Arch kernel?

Die INSTALL Datei in dem Link den Du in sources() hast bezieht sich noch auf kernel 2.6.x., sehr veraltet...
http://svn.code.sf.net/p/line6linux/cod … x2/INSTALL

Offline

#4 22.02.2016 11:23:11

sekret
Mitglied

Re: line6usb- driver PKGBUILD

$ makepkg -sirfcL
==> Making package: line6usb 0.9.1beta-1 (Mon Feb 22 09:57:39 CET 2016)
==> Checking runtime dependencies...
==> Checking buildtime dependencies...
==> Retrieving sources...
  -> Downloading ux2...
  % Total    % Received % Xferd  Average Speed   Time    Time     Time  Current
                                 Dload  Upload   Total   Spent    Left  Speed
100   350  100   350    0     0    558      0 --:--:-- --:--:-- --:--:--   558
100  3977  100  3977    0     0   4943      0 --:--:-- --:--:-- --:--:--  4943
==> Validating source files with md5sums...
    ux2 ... Passed
==> Extracting sources...
==> Starting build()...
==> Connecting to SVN server....
svn: E205000: Syntax error in revision argument '0.9.1beta'
==> ERROR: A failure occurred in build().
    Aborting...

Eieiei!!! big_smile

Hab jetzt mal kurz angefangen, das zu verbessern, aber evtl brauchst du es ja garnicht. Meine Version baut bei mir auch nicht, aber vielleicht hilft es dir ja für zukünftige Pakete.

# Maintainer: DirkKitsch <dikkitsch@unitybox.de>
pkgname=line6usb
pkgver=0.9.1beta
pkgrel=1
pkgdesc="usb driver for line6 ux2"
arch=(any)
url="https://sourceforge.net/projects/line6linux/"
license=('GPL2')
depends=()
makedepends=('subversion')
source=("svn+http://svn.code.sf.net/p/line6linux/code/driver/branches/ux2")
md5sums=('SKIP')

build() {
  cd "$srcdir/ux2"
  make
}

package() {
  cd "$srcdir/ux2"
  make DESTDIR="$pkgdir/" install
}
$ makepkg -sirfcL
==> Making package: line6usb 0.9.1beta-1 (Mon Feb 22 10:22:14 CET 2016)
==> Checking runtime dependencies...
==> Checking buildtime dependencies...
==> Retrieving sources...
  -> Updating ux2 svn repo...
Updating '.':
At revision 1085.
==> Validating source files with md5sums...
    ux2 ... Skipped
==> Extracting sources...
  -> Creating working copy of ux2 svn repo...
==> Starting build()...
./set_revision.sh
./set_revision.sh: line 9: test: too many arguments
make -C /lib/modules/4.4.1-2-ARCH/build CONFIG_LINE6_USB=m SUBDIRS=/tmp/line6/src/ux2 modules
make[1]: Entering directory '/usr/lib/modules/4.4.1-2-ARCH/build'
make[1]: *** No rule to make target 'modules'.  Stop.
make[1]: Leaving directory '/usr/lib/modules/4.4.1-2-ARCH/build'
GNUmakefile:13: recipe for target 'default' failed
make: *** [default] Error 2
==> ERROR: A failure occurred in build().
    Aborting...

Offline

#5 22.02.2016 11:50:21

Dedik
Mitglied

Re: line6usb- driver PKGBUILD

@skull-y: grad wollte ich die Fehlermeldung posten, da kam mir sekret zuvor. Genau so sah es bei mir auch aus.

@michi: Das snd-usb-line6 modul ist geladen, aber jack startet nicht. An meinem Notebook (mit pulseaudio) startet zwar jack aber das UX2 macht nichts außer leuchten. neutral
              Eine aktuellere Version hab ich nicht gefunden, hab mich mal in die mailing-list eingetragen, frageda mal nach.

@sekret: Vielen Dank. Das hilft zwar im Moment noch nicht weiter, war aber für mich sehr erhellend.

Offline

#6 22.02.2016 16:22:06

michi
Mitglied

Re: line6usb- driver PKGBUILD

@Dedik: Noch ein paar Kleinigkeiten zur Orientierung für zukünftige Pakete.

Da es ein SVN Paket ist könnte/sollte man noch den Paketnamen anpassen und pkgver() verwenden.
https://wiki.archlinux.org/index.php/VC … guidelines

Bei Paketen die für eine bestimmte Architektur kompiliert werden müssen sollte nicht arch=('any') verwendet werden.

Das ganze würde dann etwa so aussehen.

#  Maintainer: DirkKitsch <dikkitsch@unitybox.de>
pkgname=line6usb-svn
pkgver=r1085
pkgrel=1
pkgdesc="usb driver for line6 ux2"
arch=('i686' 'x86_64')
url="https://sourceforge.net/projects/line6linux/"
license=('GPL2')
groups=(line6linux)
depends=()
makedepends=('subversion')
source=("svn+http://svn.code.sf.net/p/line6linux/code/driver/branches/ux2")
md5sums=('SKIP')

pkgver() {
  cd "ux2"
  local ver="$(svnversion)"
  printf "r%s" "${ver//[[:alpha:]]}"
}

build() {
  cd "$srcdir/ux2"
  make
}

package() {
  cd "$srcdir/ux2"
  make DESTDIR="$pkgdir/" install
}

Offline

Schnellantwort auf dieses Thema

Schreibe deinen Beitrag und versende ihn
Deine Antwort

Fußzeile des Forums