Schard-nologin schriebDas Problem
gab es schon ein Mal.
Am besten machst du einen neuen Bugreport auf.
Gibt es schon. Leider scheint Upstream Flatpaks für eine tolle Sache zu halten, so dass nicht so bald mit einer stabilen Version zu rechnen ist, die in den Repos landen könnte.
Mit angepassten PKGBUILDs kann man aber pitivi-git bauen, und es läuft auch.
# Maintainer: Lubosz Sarnecki <lubosz@gmail.com>
# Contributor: Kerrick Staley <mail@kerrickstaley.com>
# Contributor: Thomas Schneider <maxmusterm@gmail.com>
# Contributor: Abhishek Dasgupta <abhidg@gmail.com>
# Contributor: Gabor Nyekhelyi (n0gabor) <n0gabor@vipmail.hu>
pkgname=pitivi-git
pkgver=0.98.163.gf3380539
pkgrel=1
pkgdesc='Edit audio/video projects based on the GStreamer framework (Git version)'
arch=('x86_64')
license=('LGPL')
depends=('gst-plugins-base' 'gst-plugins-bad' 'gobject-introspection' 'python' 'python-gobject' 'goocanvas' 'gst-python' 'gst-editing-services' 'python-xdg' 'desktop-file-utils' 'python-numpy' 'gst-transcoder-git' 'python-matplotlib' 'python-cairo')
makedepends=('automake' 'libtool' 'intltool' 'itstool' 'pygobject-devel' 'gtk-doc' 'gnome-doc-utils' 'yelp-tools' 'gst-validate')
optdepends=('python-pycanberra-git: sound notifications')
provides=('pitivi')
conflicts=('pitivi')
url='http://www.pitivi.org/'
source=('git://git.gnome.org/pitivi')
_gitname='pitivi'
md5sums=('SKIP')
pkgver() {
cd $_gitname
git describe | tr - .
}
build() {
cd $_gitname
./configure --prefix=/usr
make
}
package() {
cd $_gitname
make DESTDIR="$pkgdir" install
}
Dazu benötigt man ein angepasstes PKGBUILD für gst-validate
# Contributor: Jan de Groot <jgc@archlinux.org>
pkgname=gst-validate
pkgver=1.12.0
pkgrel=1
pkgdesc="GStreamer Validate testing Framework"
arch=('i686' 'x86_64')
license=('LGPL')
url="http://gstreamer.freedesktop.org/"
depends=('gstreamer' 'gst-plugins-base')
makedepends=('intltool' 'pkgconfig' 'gtk-doc' 'gobject-introspection' 'python' 'python-sphinxcontrib-websupport')
source=(${url}/src/gst-validate/gst-validate-${pkgver}.tar.xz)
sha256sums=('73efaf123638b97159c1ff6575dd05ea0cf7dc6d71b07806b5a5f25188a67fbb')
build() {
cd "${srcdir}/gst-validate-${pkgver}"
export PYTHON=/usr/bin/python2
./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var --libexecdir=/usr/lib
make
}
check() {
cd "${srcdir}/gst-validate-${pkgver}"
make check || true
}
package() {
cd "${srcdir}/gst-validate-${pkgver}"
make DESTDIR="${pkgdir}" install
}